Проект - 2. Текстовые компоненты, коллекция объектов

Проект будет состоять из двух модулей (одна форма), потому что отдельный модуль (Kinto) выделен для описания класса TKentavr.
Еще один двухмодульный проект, разработка и создание которого подробно описаны, Вы найдете здесь

Модуль Kinto - содержит описание (самодельного) класса TKentavr.
1-я форма - Form1, модуль - Unit1.

При изучении этого проекта полезно заглядывать в учебник А.Я. Архангельского: классы и: Конструкторы и деструкторы ( при изучении создания класса TKentavr)

1-й этап: открывать файлы с картинками, создавать описания и названия к этим картинкам и сохранять в памяти в виде списка. Названия картинок помещать с окно списка ListBox, причем при щелчке по названию картинки - показывать картинку и ее описание.

2-й этап: добавить операции: сохранения созданного в памяти списка в файле на диске, чтения такого списка из файла, удаления выделенного элемента списка.

1-й этап

Если Вы хотите создать проект по шагам, то: запустим Делфи, не будем пока трогать автоматически сформированный Unit1 и создадим новый модуль - Kinto.pas в котором разместим описание объекта. Для создания нового модуля: в меню - File | New | Unit. В окне редактора появится заготовка модуля. Можно сразу же ее сохранить: меню | File | Save as При сохранении настройтесь на папку, в которой должен храниться проект (если папки нет - создайте (для этого в окне есть кнопка)), затем в окошке "Имя файла" замените имя на "Kinto.pas". Заодно сохраните Unit1.pas и My_List.dpr (при сохранении замените имя Project1.dpr на My_List.dpr). Затем откройте в редакторе модуль Kinto (Если не открыт: меню | Project | Add to Project и выберите Kinto.pas). Когда Kinto.pas откроется в окне редактора, впишите (или скопируйте ) текст модуля Kinto из этого окошка в редактор. Обратите внимание, что имя модуля (в верхней части окна) должно совпадать с именем файла, в котором он хранится (у файла добавляется расширение .pas).

Далее обсудим текст модуля Kinto.

unit Kinto;

interface uses Graphics, Classes;

type
  TKentavr = Class
  private	// доступно только в этом модуле
  FBMP1: TBitMap;
  FOpisan: String;
  FNazvan: String;
  FErr: Boolean;
  public  // доступно во всем проекте
  property Opisan: String read FOpisan write FOpisan;
  property Nazvan: String read FNazvan write FNazvan;
  property BMP1: TBitMap read FBMP1 write FBMP1;
  property Err: Boolean read FErr;
  constructor Create;
  destructor Destroy; override;
  procedure Assign(Source: TPersistent);
  procedure SaveToStream(Stream: TStream);
  procedure LoadFromStream(Stream: TStream);
  end;

implementation

constructor TKentavr.Create;
begin
inherited;
FBMP1 := TBitmap.Create;
FErr := false; 
end;

destructor TKentavr.Destroy;
begin
FBMP1.Free;
inherited;
end;

procedure TKentavr.Assign(Source: TPersistent);
begin
  FBMP1.Assign(Source);
end;

procedure TKentavr.SaveToStream(Stream: TStream);
Var Len: Integer;
begin
  Len := Length(FNazvan);  //длина строки FNazvan
  Stream.Write(Len,4);//записываем длину FNazvan в поток Stream.
  // Поток в данном случае - параметр метода, поэтому реально
  // существующий поток должен быть передан при вызове метода.
  Stream.Write(FNazvan[1],Len);// записываем FNazvan

  Len := Length(FOpisan);  //длина строки FOpisan
  Stream.Write(Len,4);//записываем длину FOpisan
  Stream.Write(FOpisan[1],Len);// записываем FOpisan

  FBMP1.SaveToStream(Stream);
end;

procedure TKentavr.LoadFromStream(Stream: TStream);
Var Len, read1: Integer;
begin

  read1:= Stream.Read(Len,4);
  //из потока нужно прочесть 4 байта, и поместить их в
  //переменную Len. Это – длина строки, которая будет прочтена.
  if read1 < 4 then // когда файл закончится read1 будет = 0
    begin
      FErr := true; exit;
    end else
     FErr := false;

  SetLength(FNazvan,Len);  //установим размер строки = Len байт
  Stream.Read(FNazvan[1],Len); //Читаем из потока Len байт, помещаем
  //в строку FNazvan, начиная с 1-го символа строки.

  Stream.Read(Len,4); //из потока прочтено 4 байта, помещено в
  //переменную Len. Это – длина 2-й строки, которая будет прочтена.

  SetLength(FOpisan,Len);  //установим размер строки = Len байт
  Stream.Read(FOpisan[1],Len); //Читаем из потока Len байт, помещаем
  //в строку FNazvan, начиная с 1-го символа строки.

  FBMP1.LoadFromStream(Stream);
end;
end.

Решение 1-го этапа можно, конечно, выполнять по разному. Для хранения картинки с описанием будем использовать объект, поэтому придется разработать описание соответствующего класса.
Имя класса рекомендуется начинать с T, поэтому - TKentavr.
Для хранения картинки, названия и описания, естественно, должны быть поля: FBMP1: TBitMap; FOpisan: String; FNazvan: String (имена полей рекомендуется начинать с F).
Для сигнализации об ошибке при чтении объекта из файла заведем поле FErr: Boolean;
Согласно принципа инкапсуляции описания этих полей должны размещаться в разделе private (доступно только в этом модуле)
Для того чтобы работать с данными этих полей, добавляем в класс (в разделе public) свойства:
property Opisan: String read FOpisan write FOpisan; property Nazvan: String read FNazvan write FNazvan; property BMP1: TBitMap read FBMP1 write FBMP1; property Err: Boolean read FErr;
Для работы объектов класса TKentavr необходимо, чтобы поле FBMP1 было объектом инициализированным. Для этого необходим конструктор. Добавляем:
```
  constructor Create; - в раздел public и его реализацию 
    в раздел implementation модуля Kinto:

constructor TKentavr.Create;
begin
inherited;
FBMP1 := TBitmap.Create;
FErr := false;          // 
end; 
```
Но если мы создаем объект и выделяем для него память, то должны сделать и обратное - освободить эту память. Так что необходимо добавить и деструктор (тоже в public).
Последнее, что осталось - как-то передать картинку полю FBMP1. Для этого классу добавлен метод Assign.
Примечания:
1. Чтобы пользоваться описанием класса TKentavr в других модулях, в них нужно добавить модуль Kinto в предложение uses - см, например, Unit1.
2. В начале создания модуля Kinto его раздел interface не содержал uses. Однако при добавлении FBMP1: TBitMap; появляется сообщение об ошибке: неизвестно, что такое TBitMap. Ставлю курсор на TBitMap и нажимаю F1. Появляется справка о TBitMap, в которой, в частности, указано: Unit Graphics. Теперь ясно, что TBitMap описан в модуле Graphics, поэтому я должен добавить: uses Graphics (в раздел interface, потому что ошибка возникала в разделе interface). Позже та жа история - при добавлении procedure Assign(Source: TPersistent); - не известно, что такое TPersistent. Узнаю, что TPersistent описан в модуле Classes и добавляю его в uses.
3. Имя (Kinto) присваивается модулю при сохранении.
Вроде бы, это все. Займемся 2-м этапом.
2-й этап
Создадим метод (процедуру) для записи этого объекта в поток. При этом учтем, что запись картинки в поток можно обеспечить методом SaveToStream поля FBMP1, остальные поля придется записывать индивидуально. Кстати - что такое поток ? Поток - это штуковина более общая, чем файл, в частности поток может храниться в оперативной памяти. Но мы будем использовать поток, прикрепленный к файлу, так что в данном проекте поток - это просто один из способов доступа к файлу. Текст метода SaveToStream - с комментариями см выше, в модуле Kinto.pas
Теперь создадим метод LoadFromStream для чтения объекта. Здесь все наоборот (по отношению к SaveToStream), но поля читаются из потока в том же порядке, в котором записывались. Однако пришлось отслеживать ошибку, которая неизбежно возникнет при циклическом чтении объектов из файла (а именно такова конечная цель). Когда все объекты в файле будут прочтены, то при очередном выполнении оператора
read1:= Stream.Read(Len,4); ничего не будет прочтено и read1 получит значение нуль. Метод на это реагирует установлением поля FErr := true и прекращением работы. А в модуле Unit1 при чтении файла в цикле контролируется значение св-ва Err и когда оно = true, цикл прекращается. Текст метода LoadFromStream см выше, в модуле Kinto.pas

Напишем процедуру для удаления выделенного элемента. Она описана в модуле Unit1, поэтому перейдем теперь к этому модулю.

Текст модуля:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, Menus, ComCtrls, StdCtrls, ExtCtrls, ExtDlgs;

type

  TForm1 = class(TForm)
    ListBox1: TListBox;
    OpenPictureDialog1: TOpenPictureDialog;
    Image1: TImage;
    Label2: TLabel;
    memOpisan: TMemo;
    MainMenu1: TMainMenu;
    File1: TMenuItem;
    Add: TMenuItem;
    Delete: TMenuItem;
    Read_Picture: TMenuItem;
    ReadList: TMenuItem;
    WriteList: TMenuItem;
    Exit2: TMenuItem;
    Label1: TLabel;
    edNazvan: TEdit;
    SD1: TSaveDialog;
    OD1: TOpenDialog;
    procedure ListBox1Click(Sender: TObject);
    procedure Read_PictureClick(Sender: TObject);
    procedure Exit2Click(Sender: TObject);
    procedure AddClick(Sender: TObject);
    procedure WriteListClick(Sender: TObject);
    procedure ReadListClick(Sender: TObject);
    procedure DeleteClick(Sender: TObject);
  private
    { Private declarations }
  Procedure Maxi;
  public
    { Public declarations }
  end;

var
  Form1: TForm1; FName : String;

implementation uses Kinto;

{$R *.dfm}

Var Ind1: Integer;  Kent,Kent2: TKentavr;

Function Max(a,b: Integer):Integer;
begin  // Возвращает наибольшее из значений параметров a или b 
 If A > B then result := a else result := b;
end;

Procedure TForm1.Maxi;
Var Maxa: Integer;
begin // Определяет клиентские размеры формы – т к размеры картинки 
 // меняются
 maxa := Image1.left+Image1.width + 10;
 // координата правой границы картинки
 ClientWidth := maxa + 2;
 maxa := Max(edNazvan.Top + edNazvan.height,//Координата низа edNazvan
 Image1.Top + Image1.Height); //Координата низа Image1
 ClientHeight := Maxa+30;// Учет наличия полосы StatusBar1
end;

procedure TForm1.ListBox1Click(Sender: TObject);
Var Ind: Integer; //при щелчке по строке ListBox1 показываем картинку,
 // связанную с этой строкой и содержимое полей объекта
begin
 Ind := ListBox1.ItemIndex; // Индекс выделенной строки
 If Ind < 0 then
  begin beep; ShowMessage('Не выделен элемент'); exit;
  end;
 //ссылку на объект, который хранится в //ListBox1.Items.Objects[Ind]
 // копируем в переменную-объект Kent, затем – поле Kent.FBMP копируем
 // в свойство .Picture.BitMap компонента Image1
 // в результате картинка появляется на форме.

 Kent:= ListBox1.Items.Objects[Ind] as TKentavr;
 Image1.Picture.Bitmap.Assign(Kent.BMP1);
 Maxi; //Перестраиваем размеры формы, т к сменилась картинка.
 MemOpisan.Clear;
 MemOpisan.Text := Kent.Opisan; //Заполняем текст MemOpisan
 edNazvan.Text := Kent.Nazvan; //ListBox1.Items[Ind];
end;

procedure TForm1.Read_PictureClick(Sender: TObject);
//Выбрать файл с картиной
begin
 If OpenPictureDialog1.Execute then //диалог позволяет выбрать файл.
  begin
    Image1.Picture.LoadFromFile(OpenPictureDialog1.FileName);
    Maxi; //вычисляем новые клиентские размеры формы, чтобы вся картинка была видна. 
  end;
end;

procedure TForm1.Exit2Click(Sender: TObject);
begin  //выход из программы
 Application.Terminate;
end;

procedure TForm1.AddClick(Sender: TObject);
begin // Добавить сформированный объект Kent2 в список
  Kent2 := TKentavr.Create;
  Kent2.Assign(Image1.Picture.Bitmap);
  Kent2.Opisan := MemOpisan.Text;
  Kent2.Nazvan := edNazvan.Text;
  Ind1:=ListBox1.Items.AddObject(edNazvan.text,Kent2);
  ListBox1.ItemIndex := Ind1;
end;

procedure TForm1.WriteListClick(Sender: TObject);
//вызывается щелчком по пункту меню «Записать список в файл»
// списки храним в файлах с расширением .lst
Var ii: Integer; s1,s2: String;
  Len: Integer; FS: TFileStream;
begin
 if ListBox1.Count = 0 then
   begin
     showmessage('Список пустой. Не записываю');
     exit;
   end;
 if SD1.Execute then FName:= SD1.FileName else exit;
 FS := TFileStream.Create(FName,fmCreate);
//создаем поток для записи, связанный с файлом
 for ii:=1 to ListBox1.Count do
  begin Kent:= ListBox1.Items.Objects[ii-1] as TKentavr;
//циклически меняется переменная ii от 1 до числа элементов в списке.
//Переменной Kent (объявлена статически, поэтому создавать ее не надо)
//присваивается значение (ii-1)-го объекта списка, причем результат
//преобразуется к типу TKentavr при помощи оператора as TKentavr.
   Kent.SaveToStream(FS);
  end;

  FS.Free; //закрываем и освобождаем поток.
  ListBox1.Clear;
  edNazvan.Clear;
  memOpisan.Clear;
end;

procedure TForm1.ReadListClick(Sender: TObject);
//Щелчок по пункту меню «Прочесть список из файла»
//- чтение данных из потока.

Var s1,s2,s3: String;  Kent: TKentavr;
  Len,read1: Integer; FS: TFileStream;
begin
 if OD1.Execute then FName:= OD1.FileName else exit;
 FS := TFileStream.Create(FName,fmOpenRead);
//создан объект класса TFileStream только для чтения
 ListBox1.Clear; // чистим список.

 Kent := TKentavr.Create;

  While not Kent.Err do //до тех пор, пока что-то прочтено
  begin
    Kent.LoadFromStream(FS);
    if Kent.Err then break;
    ListBox1.Items.AddObject(Kent.Nazvan,Kent);
    Kent := TKentavr.Create;
  end;

  Kent.Free;
  ListBox1.ItemIndex := 0; //выделим первый элемент списка (индекс =0)
//  ListBox1Click(Sender); //исполним процедуру щелчка по списку ListBox1
  FS.Free; //освобождаем поток, так как он не нужен (всё прочтено)
end;

procedure TForm1.DeleteClick(Sender: TObject);
begin
  ListBox1.Items.Objects[ListBox1.ItemIndex].Free; // освобождаем объект.
  ListBox1.DeleteSelected; // удаляем выделенный элемент
end;

end.

Обсудим текст этого модуля:

Если Вы создаете проект по шагам, то рано или поздно (после создания модуля Kinto) Вы займетесь модулем Unit1.
При автоматическом создании проекта именно форма Form1, описанная в Unit1 становится главной ( т е ожидается нажатие на кнопку или выбор пункта меню этой формы. - имею в виду простой типичный проект). Чтобы посмотреть, какая форма проекта является главной: Меню | Project | Options | Forms. Здесь, в окошке "Main form" видим имя главной формы: Form1 (и можем его заменить - выбором из списка - но в нашем проекте нет других форм).
На форму1 нужно перенести с панели компонентов (что именно: ВИДНО в описаниии TForm1 и я копирую оттуда): ListBox1: TListBox; OpenPictureDialog1: TOpenPictureDialog; Image1: TImage; Label2: TLabel; memOpisan: TMemo; MainMenu1: TMainMenu; Label1: TLabel; edNazvan: TEdit; SD1: TSaveDialog; OD1: TOpenDialog;
Пункты меню создаются в конструкторе меню (см ниже)
Как именно их разместить, видно на работающем проекте. Заметим, что св-ва класса TMenuItem отдельно не устанавливаются, а появляются при конструировании меню (см ниже). Компоненты TLabel - это надписи.
Редактор edNazvan - для вписывания названия картинки. Его св-во Name изменено с Edit1 на edNazvan, чтобы было понятнее - для чего он. Не используйте русских букв для Name (это должен быть идентификатор Паскаля).
ListBox1 - для хранения названий списка и выбора из списка (мышещелчком). Кроме того, его свойство Items:TStrings хранит и указатели на объекты класса TKentavr, которые (объекты) в свою очередь, хранят картинку, описание и название (картинки).
OpenPictureDialog1 - для выбора файла картинки на диске, чтобы добавить эту картинку в список. Метод Execute этого объекта выводит диалоговое окно для поиска файла, а его св-во FileName сохраняет имя выбранного Вами файла. Если Вы отказались от выбора, метод Execute (так как является функцией типа Boolean) ВОЗВРАЩАЕТ false (проследите это в тексте - метод TForm1.Read_PictureClick). Настройка в инспекторе:
Св-во Title - Задайте заголовок окошка, например: "Выберите файл картинки"
Св-во InitialDir - путь к папке, с которой начинать поиск. Обычно . (точка - текущая папка, т е папка проекта). Св-во Filter - фильтр. Щелкните кнопку ... (справа от св-ва Filter) в инспекторе (при выделенном OD1 или SD1 или OpenPictureDialog1), чтобы увидеть пример.
Image1 - изображает окно на форме - для показа картинки. Не забудьте установить его св-во AutoSize = true, чтобы размеры окна подстраивались под размер картинки. Одновременно нужно изменить размеры формы (см снова TForm1.Read_PictureClick и TForm1.Maxi). Конечно, можно просто сделать большую форму.
memOpisan - компонент для хранения многострочного текста - хранит описание картинки. Если Ваши описания не помещаются - Вы можете изменить его св-во ScrollBars - например, установите = ssVertical
MainMenu1 - главное меню. Создание главного меню рассмотрим подробнее
1. Перенесем компонент MainMenu с панели компонетов на форму.
2. Для конструирования меню - двойной щелчок по этому компоненту на форме. Появится окошко конструктора меню и в нем выделен первый пункт меню. Впишите в инспекторе объектов св-во Caption этого пункта (здесь это: Файл). В св-ве Name запишите, например: File1. (File - зарезервированное слово - нельзя).
3. Теперь создадим подпункты этого пункта.
4. Для этого щелкнем по "Файл" в окне конструктора. Ниже появится пустой пункт.
5. Выделим этот новый пункт щелчком. И точно так же в окошках инспектора впишем Read_Picture (это Name) и Прочесть картинку (это Caption). Если мы хотим, чтобы этот пункт срабатывал от горячей клавиши "р"(русское), то должны вписать П&рочесть картинку в Caption (и Ф&айл - для пункта File1). Тогда при нажатии Alt а, а затем Alt р будет срабатывать пункт Read_Picture (это сделано в проекте. Не забудьте перейти на русский язык).
6. Остальные пункты меню создаются так же. Затем закройте конструктор меню. После этого меню будет работать при дизайне Form1. Если выбрать какой-то пункт, то будет создан шаблон разработчика и Вы можете его дополнить. Но это можно делать и в конструкторе (вкладка Events, событие OnClick).
SD1 - для выбора папки и ввода имени при сохранении списка. Настраивается аналогично OpenPictureDialog1 (см выше).
OD1 - для выбора файла со списком - чтобы открыть. Настраивается аналогично OpenPictureDialog1 (см выше).
Итак, компонеты установлены. Однако, их настройки (которые производились при помощи инспектора объектов - не отражаются в тексте модуля, и это может привести к ошибкам). Чтобы увидеть эти настройки, есть 2 пути.
1-й - открыть проект, выделить на форме интересующий Вас объект и просмотреть окно инспектора. Свойства, которые устанавливал програмист ВЫДЕЛЕНЫ жирным. На закладке Events Вы увидите созданные обработчики событий
2-й - открыть файл Unit1.dfm в текстовом редакторе. Там записаны все объекты с установленными свойствами и обработчики событий. Но Unit1.dfm может быть записан и в объектном формате. Тогда откройте проект и сделайте правый щелчок на форме. Затем выберите View As text - и Вы увидите текстовое представление Unit1.dfm. Для возврата - правый щелчок по тексту и выбрать View As form.
Обратите внимание, что в Unit1 должна быть ссылка на Kinto, иначе использовать описанный там класс TKentavr будет невозможно. (т е implementation uses Kinto; )
Для работы проекта нужны еще: Function Max, Procedure TForm1.Maxi; - не забудбье их записать, описания переменных и обработчики событий.
Рассмотрим, как вводить обработчики событий (на примере TForm1.ListBox1Click) при пошаговом создании проекта (по-моему, это полезно освоить)
1. Выделим (щелчком) ListBox1 на форме, затем перейдем в инспекторе объектов на закладку Events и сделаем двойной щелчок в поле правее OnClick. Тогда в редакторе появится пустой шаблон - заготовка для создания обработчика события OnClick. Вы вписываете (или копируете) в него что нужно из текста модуля и обработчик готов. Это универсальный способ для всех обработчиков. Но у каждого компонента есть "избранный" обработчик, шаблон которого создается просто двойным щелчком по компоненту на форме. В частности, шаблон для ListBox1Click можно создать и так. Этот же прием применяется для быстрого отыскания обработчика в редакторе (когда некоторый текст там уже есть). Заодно отметим, что незаполненные обработчики удаляются автоматически при сохранении или компиляции модуля. Теперь Вы можете заполнить все обработчики: Read_PictureClick, Exit2Click, AddClick, WriteListClick, ReadListClick, DeleteClick - (это все: выбор СООТВЕТСТВУЮЩЕГО пункта меню).
  Методы класса, не являющиеся обработчиками событий (например, Procedure TForm1.Maxi; и методы класса TKentavr) записываются проще: сначала только заголовок в описание класса (в разделе interface), затем - в разделе implementation (реализация) - полный текст метода, причем перед его им енем ставится имя класса. Подпрограммы, не являющиесы элементами класса (например, Function Max) естественно, не содержат имени класса. Если такие подпрограммы нужны другим модулям, то их заголовки должны быть в разделе interface.
При работе в текстовом редакторе большую помощь оказывает автоматическая подсказка свойств и методов объекта. Если Вы, например, напишите Kent. (не забудьте точку) то появится список свойств и методов этого объекта (если в тексте, расположенном ранее точки (т е левее и выше) нет ошибок). Полезность этого не столько в ускорении ввода текста, сколько в контроле отсутствия ошибок. Попробуйте, например, следующее:
В метод ListBox1Click добавьте описание переменной ss: string; Затем перед end этого метода впишите: ss := Kent. Как только появится точка, появится и подсказка в виде возможных полей и методов. Там будут Opisan и Nazvan - вполне реальные варианты. Если же Вы впишите: ss := IntToStr(Kent. то список возможных завершений будет другой. Если же в тексте есть ошибка, исключающая возможность завершения, то завершения не будет, внизу будет предупреждение об ошибке. После некоторой практики такую страховку от ошибок использовать удобно (все мы - люди и поначалу для нас не все доходит).
Теперь проект готов. Для его трансляции и выполнения нажмите F9. Конечно, вначале будут ошибки. Ошибки выделяются красной строкой, а текст сообщения появляется внизу, в окне ошибок редактора (англ). Вообще то программист должен немного знать английский, если нет - пользуйтесь программой - переводчиком (например TranlateIt, который переводит при простом наведении курсора на неясное слово)
Надеюсь, Вы устраните все ошибки и программа заработает.
К сожалению, есть недоработки, надеюсь, Вы их устраните:
1. При чтении списка из файла картинка не появляется, пока не щелкнете по списку для выбора.
2. При удалении из списка картинка не исчезает сразу.

Скачать RAR-архив исходников (16 Кб)
Скачать RAR-архив исходников + .exe(200 Кб)